home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Cream of the Crop 25
/
Cream of the Crop 25.iso
/
bbs
/
con_005c.zip
/
CONCORD.RAR
/
SCRIPT.RAR
/
NEWUSER.SCR
< prev
next >
Wrap
Text File
|
1997-04-25
|
6KB
|
222 lines
; NEWUSER.SCR : New user script
;
; This script is run in logon when a new user calls to the BBS.
;
; This script calls USERFORM.SCR script for ANSI users
; instead of asking for certain user information itself.
;
; Unremark GOSUB lines in the end of this script
; to set default combined message areas and last read pointers.
:BEGIN
write "^C12,0;Third degree interrogation begins...^M;^M;"
menutype 7 language
set @HOTKEYS@ = 1
gosub ASK_COLORS
gosub ASK_TERMEMUL
menutype 7 charset
gosub ASK_SEX
gosub ASK_DATEFMT
if @IEMSI_FOUND@ <> 1
gosub ASK_CITY
if @EMULATION@ = 4
gosub ASK_ALIAS
end
end
if @EMULATION@ = 4
gosub ASK_ADDRESS
else
call USERFORM
end
if @IEMSI_FOUND@ <> 1
if @EMULATION@ = 4
gosub ASK_HOMEPHONE
gosub ASK_DATAPHONE
gosub ASK_BIRTHDAY
gosub ASK_SCRLEN
end
end
gosub ASK_PASSWORD
goto END
:ASK_DATEFMT
write "^C15,0;Select date format :^M;"
write "^C14,0;1 ^C7,0;-^C14,0; MM-DD-YY^M;"
write "^C14,0;2 ^C7,0;-^C14,0; DD.MM.YY^M;"
write "^C15,0;Make your selection (~11,~22) [1] : ^W;^M;"
if @ANSWER@ = 2
set @DATEFORMAT@ = 21
else
set @DATEFORMAT@ = 0
end
return
:ASK_COLORS
write "^C15,0;Do you have colors? (~1Y/~2n) "
set @COLORS@ = @ANSWER@
if @ANSWER@ = 1
write "Yeah!^M;"
else
write "Nah...^M;"
end
return
:ASK_TERMEMUL
if @EMULATION@ <> 0
write "^C15,0;Use (~11) ANSI or (~22) Avatar emulation? "
set @EMULATION@ = @ANSWER@
if @ANSWER@ = 1
write "ANSI^M;"
else
write "Avatar^M;"
end
end
return
:ASK_ALIAS
set @ALIAS@ =
write "^C15,0;Alias? ^C14,1;^L35;^C15,0;^M;"
set @ALIAS@ = @ANSWER@
if @ANSWER@ = ""
write "^C15,0;Are you sure you don't want to have an alias? (~1Y/~2n) ^W;^M;"
if @ANSWER@ = 2
goto ASK_ALIAS
end
else
if @ALIAS@ = ""
write "^C15,0;Sorry, this alias is already reserved. Please select another.^M;"
goto ASK_ALIAS
end
end
return
:ASK_CITY
write "^C15,0;City or BBS name? ^C14,1;^L25;^C15,0;^M;"
if @ANSWER@ = ""
goto ASK_CITY
else
set @CITY@ = @ANSWER@
end
return
:ASK_ADDRESS
write "^C15,0;Home address (3 lines) :^M;"
write "^C15,0;1: ^C14,1;^L20;^C15,0;^M;"
if @ANSWER@ = ""
goto ASK_ADDRESS
else
set @ADDRESS1@ = @ANSWER@
end
write "^C15,0;2: ^C14,1;^L20;^C15,0;^M;"
set @ADDRESS2@ = @ANSWER@
write "^C15,0;2: ^C14,1;^L20;^C15,0;^M;"
set @ADDRESS3@ = @ANSWER@
return
:ASK_HOMEPHONE
; write "^C15,0;Home phone number? ^C14,1;^L20;^C15,0;^M;"
write "^C15,0;Home phone number? ^C14,1;^L20,(###)###-####;^C15,0;^M;"
if @ANSWER@ = ""
goto ASK_HOMEPHONE
else
set @VOICE@ = @ANSWER@
end
return
:ASK_DATAPHONE
; write "^C15,0;Data phone number? ^C14,1;^L20;^C15,0;^M;"
write "^C15,0;Data phone number? ^C14,1;^L20,(###)###-####;^C15,0;^M;"
set @DATA@ = @ANSWER@
return
:ASK_BIRTHDAY
var %BDAYTEMP% = DATE
; write "^C15,0;Birthday? (@CURRDATEFMT@) ^C14,1;^L8;^C15,0;^M;"
write "^C15,0;Birthday? (@CURRDATEFMT@) ^C14,1;^L8,##-##-##;^C15,0;^M;"
set %BDAYTEMP% = @ANSWER@
if %BDAYTEMP% = ""
goto ASK_BIRTHDAY
end
set @BIRTHDAY@ = @ANSWER@
if ((@AGE@ < 7) or (@AGE@ > 80))
goto ASK_BIRTHDAY
end
return
:ASK_SEX
write "^C15,0;Male or Female? (~1M/~2f) "
if @ANSWER@ = 2
write "Female^M;"
set @FEMALE@ = TRUE
else
write "Male^M;"
set @FEMALE@ = FALSE
end
return
:ASK_SCRLEN
set @DEFAULT_ANSWER@ = 24
write "^C15,0;Your screen length? ^C14,1;^L2;^C15,0;^M;"
if ((@ANSWER@ < 20) or (@ANSWER@ > 100))
write "^C15,0;Sorry, only values between 20 and 100 are allowed.^M;"
goto ASK_SCRLEN
else
set @SCREENLEN@ = @ANSWER@
return
end
:ASK_PASSWORD
var %PASSTEMP% = STRING 15
write "^C15,0;Password? ^C14,1;^L15,HIDDEN;^C15,0;^M;"
if @ANSWER@ = ""
goto ASK_PASSWORD
end
set %PASSTEMP% = @ANSWER@
write "^C15,0;Once again: ^C14,1;^L15,HIDDEN;^C15,0;^M;"
if "%PASSTEMP%" = "@ANSWER@"
set @PASSWORD@ = @ANSWER@
return
else
write "^C12,0;WRONG! Try again...^M;"
goto ASK_PASSWORD
end
:SET_AREAS
; See SET MSG AREAS menutype documents for correct parameters.
;
; "ALL OFF" will turn off all message areas.
;
write "^C7,0;■ ^C15,0;Clearing default combined message areas^M;"
menutype 200f ALL OFF
return
:SET_POINTERS
; See SET LAST READ PTR menutype documents for correct parameters.
;
; "ALL MAX" will set pointers to the end of the messages.
;
write "^C7,0;■ ^C15,0;Setting last read pointers to end of messages^M;"
menutype 200f ALL MAX
return
:END
write "^C12,0;Thank you very much for completing this questionnaire.^M;"
write "^C12,0;You should now check your settings from Setup menu,^M;"
write "^C12,0;after which you are free to go.^M;^M;"
;
; Remove semicolon from the beginning of next GOSUB lines
; to set default combined message areas and last read pointers :
;
; gosub SET_AREAS
; gosub SET_POINTERS
;
QUIT